(
	thumbnailViewerDll = ( (getDir #maxRoot) + "thumbnailViewer.dll") -- ***Point this path to where you placed the .dll file
	if (doesFileExist thumbnailViewerDll) do
	(
		dotNet.loadAssembly thumbnailViewerDll -- Load assembly before creating control
		
		rollout dialog_thumbnailViewer "Thumbnail Viewer Example"
		(
			dotNetControl thumbnailViewer "maxCustomControl.thumbnailViewer" height:200 width:450 align:#center
			
			on dialog_thumbnailViewer open do
			(
				processStart = timeStamp()
				
				thumbnailViewer.setItemsPerRow 3
				thumbnailViewer.showItemsExitButton true
				
			-- Get images	
				mainDir = @"C:\Users\Jason\Desktop\work\c#_projects\thumbnailImages\" -- ***Set this to a directory to where you want to get images from
				imageFiles = getFiles (mainDir + "*.jpg")
				
			-- Add thumbItems
				thumbItems = #()
				for x in 1 to imageFiles.count do 
				(
				-- Create thumbnailItem and set its properties	
					thumbItem = dotNetObject "maxCustomControl.thumbnailItem"
					thumbItem.setFilepath imageFiles[x]
					fileNameOnly = (getFileNameFile imageFiles[x])
					thumbItem.setLabel fileNameOnly
					thumbItem.setToolTip fileNameOnly
					thumbItem.setBackColor2 ( (dotNetClass "System.Drawing.Color").fromArgb (random 100 255) (random 100 255) (random 100 255))
					append thumbItems thumbItem
				)
				
				thumbnailViewer.addRange thumbItems
				
				processStop = timeStamp()
				format "Took % seconds to initialize % items\n" ( (processStop - processStart) / 1000.0) (thumbnailViewer.getItemsCount())
			)
			
		-- Left-click event on an item
			on thumbnailViewer thumbEvent arg do
			(
				format "Left click: % index, %\n" arg.index arg.filePath
			)
			
		-- Right-click event on an item
			on thumbnailViewer thumbRightClickEvent arg do
			(
				format "Right click: % index, %\n" arg.index arg.filePath
			)
			
		-- Event when pressing 'x' in upper-right corner	
			on thumbnailViewer exitButtonEvent arg do
			(
				removeItem = (queryBox "Warning! Are you sure you want to delete this item?" title:"Warning")
				if (removeItem) do
				(
					thumbnailViewer.removeItem arg.index
				)
			)
		)
		createDialog dialog_thumbnailViewer 500 500
	)
)

# Import all the modules we need
import sys
import clr
import os
from System.Windows.Forms import *

# Import the thumbnail dll
sys.path.append("C:/Users/Jason/Desktop/") # Point this to the directory where thumbnailViewer.dll is
clr.AddReference("thumbnailViewer")
import maxCustomControl

class thumbnailViewerForm(Form):
	def __init__(self):
		# Create the thumbnail control
		self.thumbControl = maxCustomControl.thumbnailViewer()
		self.thumbControl.Width = 280
		self.thumbControl.Height = 150

		# Populate the control with images
		imageDirectory = "C:/Users/Jason/Desktop/thumbnailImages/"
		if os.path.exists(imageDirectory):
			thumbnailItems = list()		
			files = os.listdir(imageDirectory)
			for f in files:
				fSplit = os.path.splitext(f)
				if (fSplit[1] == ".jpg"):
					thumbItem = maxCustomControl.thumbnailItem()
					thumbItem.setFilepath( (imageDirectory + f) )
					thumbnailItems.append(thumbItem)
	
			self.thumbControl.addRange(thumbnailItems)
		
		# Add event
		self.thumbControl.thumbEvent += self.itemClicked
		
		# Create a form
		self.f = Form()
		self.f.Text = "My form"

		self.f.Controls.Add(self.thumbControl)
		self.f.Show()
		
	# Triggered when an item is clicked
	def itemClicked(self, sender, args):
		print args.Index
		print args.FilePath

formInst = thumbnailViewerForm()